'**********************************************************************************************************
' Nazwa:                czyRozpoczynaSie
' Autor:                mielk | 2012-06-21
'
' Opis:                 Funkcja sprawdzająca czy podany tekst bazowy rozpoczyna się od określonego ciągu
'                       znaków.
'
' Argumenty:
'   bazowy              Tekst bazowy, którego początek jest sprawdzany przez funkcję.
'   sprawdzany          Ciąg znaków, który jest przez tę funkcję porównywany z początkiem tekstu bazowego.
'   wielkoscZnakowMaZnaczenie
'                       Argument opcjonalny.
'                       * Decyduje o tym, czy przy sprawdzaniu zgodności początku tekstu bazowego z
'                         podanym ciągiem znaków, funkcja bierze pod uwagę wielkość liter.
'                       * Domyślne ustawienie tego parametru to True, co oznacza, że funkcja rozróżnia
'                         wielkość znaków.
'
' Zwraca:
'   Boolean             True - jeżeli tekst bazowy rozpoczyna się od ciągu znaków, podanego jako argument
'                               sprawdzany.
'                       False - jeżeli tekst bazowy nie rozpoczyna się od ciągu znaków, podanego jako
'                               argument sprawdzany.
'
'
' --- Zmiany ----------------------------------------------------------------------------------------------
' 2012-06-21        mielk           Utworzenie funkcji.
'**********************************************************************************************************
Public Function czyRozpoczynaSie(bazowy As String, sprawdzany As String, _
                                           Optional wielkoscZnakowMaZnaczenie As Boolean = True) As Boolean
    Const NAZWA_METODY As String = "czyRozpoczynaSie"
    '------------------------------------------------------------------------------------------------------
    Dim uMetodaPorownywania As VBA.VbCompareMethod
    '------------------------------------------------------------------------------------------------------

    'Zamienia podany przez użytkownika parametr typu Boolean [wielkoscZnakowMaZnaczenie] na jedną ze ----|
    'stałych enumeracji [VbCompareMethod].                                                              '|
    If wielkoscZnakowMaZnaczenie Then                                                                   '|
        uMetodaPorownywania = VBA.vbBinaryCompare                                                       '|
    Else                                                                                                '|
        uMetodaPorownywania = VBA.vbTextCompare                                                         '|
    End If                                                                                              '|
    '----------------------------------------------------------------------------------------------------|


    '----------------------------------------------------------------------------------------------------|
    If VBA.StrComp(VBA.Left$(bazowy, VBA.Len(sprawdzany)), sprawdzany, uMetodaPorownywania) = 0 Then    '|
        czyRozpoczynaSie = True                                                                         '|
    End If                                                                                              '|
    '----------------------------------------------------------------------------------------------------|


End Function