'**********************************************************************************************************
' Nazwa:                sprawdzKoniecTekstu
' Autor:                mielk | 2012-06-21
'
' Opis:                 Sprawdza czy podany tekst kończy się podanym fragmentem tekstu.
'
' Argumenty:
'   bazowy              Tekst bazowy, którego zakończenie jest sprawdzane przez funkcję.
'   sprawdzany          Ciąg znaków, który jest przez tę funkcję porównywany z końcem tekstu bazowego.
'   wielkoscZnakowMaZnaczenie
'                       Argument opcjonalny.
'                       * Decyduje o tym, czy przy sprawdzaniu zgodności początku tekstu bazowego z
'                         podanym ciągiem znaków, funkcja bierze pod uwagę wielkość liter.
'                       * Domyślne ustawienie tego parametru to True, co oznacza, że funkcja rozróżnia
'                         wielkość znaków.
'
'
' Zwraca:
'   Boolean             True - jeżeli tekst bazowy kończy się podanym fragmentem.
'                       False - jeżeli tekst bazowy nie kończy się podanym fragmentem.
'
'
' --- Zmiany ----------------------------------------------------------------------------------------------
' 2012-06-21        mielk           Utworzenie funkcji.
'**********************************************************************************************************
Public Function sprawdzKoniecTekstu(bazowy As String, sprawdzany As String, _
                                            Optional wielkoscZnakowMaZnaczenie As Boolean = True) As Boolean
    Const NAZWA_METODY As String = "sprawdzKoniecTekstu"
    '------------------------------------------------------------------------------------------------------
    Dim uMetodaPorownania As VBA.VbCompareMethod
    '------------------------------------------------------------------------------------------------------


    'Zamienia podany przez użytkownika parametr typu Boolean [wielkoscZnakowMaZnaczenie] na jedną ze ----|
    'stałych enumeracji [VbCompareMethod].                                                              '|
    If wielkoscZnakowMaZnaczenie Then                                                                   '|
        uMetodaPorownania = VBA.vbBinaryCompare                                                         '|
    Else                                                                                                '|
        uMetodaPorownania = VBA.vbTextCompare                                                           '|
    End If                                                                                              '|
    '----------------------------------------------------------------------------------------------------|


    '----------------------------------------------------------------------------------------------------|
    If VBA.StrComp(VBA.right$(bazowy, VBA.Len(sprawdzany)), sprawdzany, uMetodaPorownania) = 0 Then     '|
        sprawdzKoniecTekstu = True                                                                      '|
    End If                                                                                              '|
    '----------------------------------------------------------------------------------------------------|


End Function